*$
************************ IGBT Electrical Parameters *******************************
** Product: FGB5065G2_F085
** 500mJ, 650V, N-Channel PTC Heater IGBT
**---------------------------------------------------------------------------------
.SUBCKT FGB5065G2_F085 1 2 3 
M1 9 6 8 8 MSUB L=2E-06 W=1.3251 
RD 7 9 1E-06 
RS 4 8 0.0025 
CGC 6 1 1E-12 
CGE 6 4 6.84E-10 
Q1 4 7 1 QSUB 
RDS 7 4 1E+08 
RER 4 3 0.0012 TC=0.006818 
RG 6 2 1.58 
RL 10 11 1 
D2 12 11 DCAP 
D3 0 11 DL 
VFI2 12 0 0 
FI2 6 7 VFI2 -1 
EV 10 0 7 6 1 
CAP 10 13 5.75E-09
RCAP 10 14 1 
D4 0 14 DL 
VFI1 13 14 0 
FI1 6 7 VFI1 -1 
RG2 6 net3 115
RGE 6 4 20k 
RGCleakage net3 1 150Meg
E0 net017 net3 1 net017 50
DGCCLP1b 1 net013       GC_CLP_Diode
DGCCLP1a net017 net013  GC_CLP_Diode
DGEESD_1a net020 net012 GE_ESD
DGEESD_1b 4 net012      GE_ESD
DGEESD_2a net3 net014   GE_ESD
DGEESD_2b net020 net014 GE_ESD
.MODEL MSUB NMOS 
+ LEVEL=7          VERSION=3.1      MOBMOD=3 
+ CAPMOD=2         PARAMCHK=1       NQSMOD=0 
+ TOX=5E-08        XJ=1.4E-06       NCH=1.3E+17 
+ U0=1131          VSAT=1E+05       DROUT=1 
+ DELTA=0.1        PSCBE2=0         RSH=0.1 
+ VTH0=1.428       VOFF=-0.1        NFACTOR=1.1 
+ LINT=3E-07       CGSO=0           CGSL=0 
+ CGDO=0           CGBO=0           CGDL=0 
+ CJ=0             CF=0             CJSW=0 
+ CKAPPA=0.12      KT1=-0.9075      KT2=0 
+ UA1=2.512E-10    NJ=10  
.model QSUB pnp 
+ IS=1.061E-14     BF=1             NF=1 
+ VAF=1500         IKF=0.772        ISE=1.048E-12
+ NE=1.5           BR=0.85          NR=1 
+ VAR=200          IKR=1000         ISC=1E-11 
+ NC=1             RB=1.231         IRB=0.009704 
+ RBM=1.734E-06    RE=1E-08         RC=0.01064 
+ XTB=2.036        XTI=13.26        EG=0.5114 
+ CJC=5.324E-10    VJC=0.75         MJC=0.62
+ CJE=5.601E-09    VJE=0.5          MJE=1.048
+ TF=1.038E-06 
.model DCAP d 
+ IS=1E-32         N=50             BV=650
+ IBV=0.01         CJO=1.523E-9    VJ=0.3469 
+ M=0.9314         FC=0.5 
.model DL d 
+ IS=1E-10         N=1
.model GE_ESD d 
+ IS=2.01E-12      N=1.5            RS=2.38 
+ M=4.795          VJ=5             FC=0.25 
+ BV=14            IBV=0.002 
.model GC_CLP_Diode d 
+ IS=1.1E-12       N=1              RS=6.88 
+ M=4.795          VJ=5             BV=560 
+ IBV=0.002 
.ENDS
*$
*
********************** Power Discrete IGBT Thermal Model ************************
** Package: D2PAK
**-------------------------------------------------------------------------------
.SUBCKT FGB5065G2_F085_Thermal TH TL
CTHERM1 TH 6 5.04e-4
CTHERM2 6 5  1.18e-3
CTHERM3 5 4  4.14e-3 
CTHERM4 4 3  7.82e-3 
CTHERM5 3 2  9.12e-3
CTHERM6 2 TL 1.52e-2
RTHERM1 TH 6 1.05e-3
RTHERM2 6 5  2.00e-3
RTHERM3 5 4  3.00e-2
RTHERM4 4 3  8.41e-2
RTHERM5 3 2  1.03e-1
RTHERM6 2 TL 2.80e-1
.ENDS FGB5065G2_F085_Thermal
**-------------------------------------------------------------------------------
** Creation: Jul.-14-2023   Rev.: 1.1
** onsemi
*$